WinExist

Checks if the specified window exists.

UniqueID := WinExist(WinTitle, WinText, ExcludeTitle, ExcludeText)

Parameters

WinTitle

Type: String, Integer or Object

A window title or other criteria identifying the target window. See WinTitle.

WinText

Type: String

If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.

ExcludeTitle

Type: String

Windows whose titles include this value will not be considered.

ExcludeText

Type: String

Windows whose text include this value will not be considered.

Return Value

Type: Integer

This function returns the Unique ID (HWND) of the first matching window (or 0 if none).

Since all non-zero numbers are seen as "true", the statement if WinExist(WinTitle) is true whenever WinTitle exists.

Remarks

If all parameters are omitted, the Last Found Window will be checked to see if it still exists.

If a qualified window exists, the Last Found Window will be updated to be that window.

To discover the HWND of a control (for use with PostMessage, SendMessage or DllCall), use ControlGetHwnd or MouseGetPos.

Window titles and text are case sensitive. Hidden windows are not detected unless DetectHiddenWindows has been turned on.

Related

WinActive, SetTitleMatchMode, DetectHiddenWindows, Last Found Window, ProcessExist, WinActivate, WinWaitActive, WinWait, WinWaitClose, #HotIf

Examples

#1

if WinExist("Untitled - Notepad")
{
    WinActivate  ; Automatically uses the window found above.
    WinMaximize  ; same
    Send "Some text.{Enter}"
    return
}

#2

if not WinExist("Calculator")
    return
else
{
    WinActivate  ; The above "WinExist" also set the "last found" window for us.
    WinMove 40, 40  ; Move it to a new position.
    return
}

#3

if WinExist("ahk_class Notepad") or WinExist("ahk_class" . ClassName)
    WinActivate  ; Uses the last found window.

MsgBox "The active window's ID is " . WinExist("A")